Konkrete Ausgangslage des Acer

• 128-GB-Kingston-M.2-SATA-SSD: Windows auf C:, 100-MB-EFI-Systempartition und etwa 1 GB WinRE
• 1-TB-Toshiba-HDD: Datenpartition mit etwa 851 GB sowie separate Recovery-Partition mit 80 GB
• Recovery-Partition: NTFS, Label RECOVERY, am Ende versteckt und ohne Standard-Laufwerksbuchstaben
• Finales Image: \RecoveryImage\Acer_XC780_Windows11.wim, etwa 25,32 GiB
• Windows 11 Home, x64, Core, Build 26200.8037, de-DE

Übertragbar sind das Offline-Capture-Prinzip, die Prüfungen und die Trennung zwischen Windows-, EFI- und WinRE-Partition. Nicht übertragbar sind Partitionsnummern, Laufwerksbuchstaben und Größen.

1. Windows vollständig vorbereiten und testen

Vor dem Image-Capture wurden Windows, Treiber, Anwendungen und die Systemwiederherstellung praktisch getestet. Ein Image konserviert auch vorhandene Fehler; deshalb gehört die Funktionsprüfung vor Sysprep.

2. WinRE kontrollieren und reparieren

reagentc /info

Auf diesem Rechner war Windows RE zunächst deaktiviert, obwohl Winre.wim auf der vorhandenen Recovery-Partition unter \Recovery\WindowsRE\Winre.wim lag. Nach eindeutiger Identifikation und temporärer Einbindung der kleinen WinRE-Partition wurde die Umgebung neu registriert:

reagentc /disable
reagentc /setreimage /path R:\Recovery\WindowsRE
reagentc /enable
reagentc /info

Danach meldete Windows RE den Status „Enabled“ und den Ort \\?\GLOBALROOT\device\harddisk0\partition4\Recovery\WindowsRE. Die WinRE-Version war 10.0.26100.8031. Die Systemwiederherstellung wurde anschließend aus WinRE getestet. Der Hilfsbuchstabe R: ist nur ein Beispiel und wird nach der Reparatur wieder entfernt.

3. Eigene Recovery-Partition auf der zweiten Festplatte

Auf der Toshiba-HDD wurde hinter der Datenpartition eine 80-GB-NTFS-Partition mit dem Label RECOVERY angelegt. Vor Änderungen mit DiskPart müssen Modell, Größe, vorhandene Volumes und freier Bereich eindeutig geprüft werden. Die folgende Struktur ist bewusst kein blind ausführbarer Befehlssatz:

diskpart
list disk
select disk <eindeutig identifizierte zweite Festplatte>
detail disk
list partition
rem Erst nach Prüfung: vorhandene Datenpartition passend verkleinern
select partition <eindeutig identifizierte Datenpartition>
shrink desired=81920
create partition primary size=81920
format fs=ntfs quick label=RECOVERY
assign letter=E
exit

mkdir E:\RecoveryImage

Die tatsächlich verwendeten 80 GB entsprachen dem geplanten Image und zusätzlicher Reserve. Vor dem Verkleinern gehört ein unabhängiges Backup wichtiger Daten zwingend dazu.

4. Sysprep: Audit Mode, OOBE und Generalize

Der Audit Mode dient zur technischen Vorbereitung eines Systems vor der Ersteinrichtung. OOBE startet beim nächsten Windows-Boot die Ersteinrichtung. /generalize entfernt systemspezifische Informationen für eine übertragbare Bereitstellung. Generalize sollte nicht unnötig mehrfach ausgeführt werden.

Bei diesem Acer war Generalize bereits zuvor erfolgt. Der abschließende Lauf verwendete deshalb OOBE ohne ein weiteres Generalize und fuhr den Rechner herunter:

%WINDIR%\System32\Sysprep\Sysprep.exe /oobe /shutdown

Danach wurde nicht mehr von C: gebootet. Jeder erneute Start des installierten Windows hätte den vorbereiteten OOBE-Zustand verändert. Stattdessen startete der Rechner direkt vom Windows-Setup-/WinPE-USB-Stick.

5. Windows offline mit DISM erfassen

Im Setup wurde mit Umschalt+F10 die Eingabeaufforderung geöffnet. Dort waren in diesem konkreten Start C: die Windows-Partition, D: DATA und E: RECOVERY. Diese Zuordnung wurde vor dem Capture über Ordnerstruktur, Label und Größe geprüft.

diskpart
list disk
list volume
exit

dir C:\Windows\System32\config\SYSTEM
dir E:\RecoveryImage

Der finale Capture-Befehl lautete:

dism /Capture-Image /ImageFile:E:\RecoveryImage\Acer_XC780_Windows11.wim /CaptureDir:C:\ /Name:"Acer XC-780 Windows 11 Recovery" /Description:"Windows 11 Home H2- OOBE Recovery 08.09.2026" /Compress:max /CheckIntegrity

Das Ergebnis war eine WIM-Datei mit etwa 25,32 GiB. Sie wurde anschließend ausgelesen:

dism /Get-WimInfo /WimFile:E:\RecoveryImage\Acer_XC780_Windows11.wim

dism /Verify-Image gehört ausdrücklich nicht zu diesem Ablauf. Der Befehl wurde in dieser Umgebung nicht unterstützt und endete mit Fehler 87. Für Capture und Apply wurde stattdessen /CheckIntegrity verwendet; zusätzlich wurde das Image mit /Get-WimInfo kontrolliert.

6. Recovery-Partition wieder verstecken

diskpart
list volume
select volume <eindeutig identifiziertes 80-GB-Volume RECOVERY>
detail volume
attributes volume set hidden
attributes volume set nodefaultdriveletter
exit

Danach war die 80-GB-Partition ohne Laufwerksbuchstaben als versteckt markiert. Ein anschließend versuchtes remove letter=E meldete „Fehler beim Dienst für virtuelle Datenträger: Der Pfad wurde nicht gefunden.“ Das war in diesem Fall harmlos: Durch die gesetzten Attribute war E: bereits verschwunden.

Sicheres Restore-Prinzip

Beim Wiederherstellen wird weder diskpart clean verwendet noch die gesamte SSD gelöscht. EFI- und WinRE-Partition bleiben unformatiert. Nur die eindeutig identifizierte Windows-Partition wird neu formatiert und anschließend mit dem WIM befüllt.

• Vom Windows-Setup-/WinPE-Stick booten und Umschalt+F10 drücken.
• Mit list disk und list volume Datenträger, Größe, Label und Dateisystem prüfen.
• Recovery-Quelle nur über die tatsächlich vorhandene Datei \RecoveryImage\Acer_XC780_Windows11.wim erkennen.
• Windows-Ziel über \Windows\System32\config\SYSTEM identifizieren.
• Bei mehreren Kandidaten oder jeder Unsicherheit abbrechen.
• Vor Format ausdrücklich Ziel, Quelle und Größe erneut anzeigen und bestätigen.

dism /Apply-Image /ImageFile:<Recovery-Laufwerk>:\RecoveryImage\Acer_XC780_Windows11.wim /Index:1 /ApplyDir:<Windows-Laufwerk>:\ /CheckIntegrity

Im normalen Restore wird kein BCDBoot aufgerufen. Der vorhandene, funktionierende EFI-Bootloader bleibt erhalten. Warum das bei diesem Acer besonders wichtig war, zeigt der verknüpfte Praxisbericht Acer Aspire XC-780: Secure-Boot-Fehler 0xc0430001. Nur wenn EFI-Bootdateien nachweislich fehlen oder beschädigt sind, ist BCDBoot ein separater Reparaturfall.

Defensives CMD-Beispiel für den Restore

Das folgende WinPE-Skript sucht nicht nur nach dem Label „RECOVERY“. Das wäre auf diesem PC mehrdeutig, weil auch die kleine WinRE-Partition „Recovery“ heißen kann. Stattdessen prüft es jedes eingebundene Laufwerk auf den exakten WIM-Pfad und bricht bei mehreren Quellen oder Windows-Zielen ab.

Vor Verwendung anpassen und testen: Dieses Beispiel ersetzt keine Sichtprüfung. Es zeigt die DiskPart-Daten vor dem Formatieren an und verlangt exakt JA. Trotzdem muss der Bediener Quelle und Ziel selbst verifizieren.

@echo off
setlocal EnableExtensions EnableDelayedExpansion

set "IMAGE_REL=\RecoveryImage\Acer_XC780_Windows11.wim"
set "REC_DRIVE="
set "WIN_DRIVE="
set /a REC_COUNT=0
set /a WIN_COUNT=0

rem X: ist normalerweise WinPE und wird bewusst nicht geprüft.
for %%D in (C D E F G H I J K L M N O P Q R S T U V W Y Z) do (
  if exist "%%D:%IMAGE_REL%" (
    set /a REC_COUNT+=1
    set "REC_DRIVE=%%D:"
    echo Recovery-Kandidat: %%D:%IMAGE_REL%
  )
  if exist "%%D:\Windows\System32\config\SYSTEM" (
    set /a WIN_COUNT+=1
    set "WIN_DRIVE=%%D:"
    echo Windows-Kandidat: %%D:\Windows\System32\config\SYSTEM
  )
)

if not "!REC_COUNT!"=="1" (
  echo ABBRUCH: Es wurden !REC_COUNT! eindeutige Recovery-Quellen gefunden.
  goto :fail
)
if not "!WIN_COUNT!"=="1" (
  echo ABBRUCH: Es wurden !WIN_COUNT! eindeutige Windows-Ziele gefunden.
  goto :fail
)
if /I "!REC_DRIVE!"=="!WIN_DRIVE!" (
  echo ABBRUCH: Quelle und Ziel liegen auf demselben Laufwerksbuchstaben.
  goto :fail
)

echo.
echo Gefundene Recovery-Quelle: !REC_DRIVE!%IMAGE_REL%
echo Gefundenes Windows-Ziel:   !WIN_DRIVE!\
echo.

set "DPSCRIPT=%TEMP%\pcnetprofi-disks.txt"
>"!DPSCRIPT!" echo list disk
>>"!DPSCRIPT!" echo list volume
>>"!DPSCRIPT!" echo select volume !REC_DRIVE:~0,1!
>>"!DPSCRIPT!" echo detail volume
>>"!DPSCRIPT!" echo select volume !WIN_DRIVE:~0,1!
>>"!DPSCRIPT!" echo detail volume
>>"!DPSCRIPT!" echo exit
diskpart /s "!DPSCRIPT!"
del "!DPSCRIPT!"

echo.
echo PRUEFEN: Datentraeger, Groesse, Label, Dateisystem und Pfade.
echo Nur !WIN_DRIVE! wird formatiert. EFI, WinRE und andere Volumes bleiben erhalten.
set "CONFIRM="
set /p "CONFIRM=Zum Formatieren von !WIN_DRIVE! exakt JA eingeben: "
if not "!CONFIRM!"=="JA" (
  echo Abgebrochen. Es wurden keine Daten formatiert.
  goto :fail
)

format !WIN_DRIVE! /FS:NTFS /Q /V:Windows
if errorlevel 1 (
  echo FEHLER: Formatierung fehlgeschlagen. DISM wird nicht gestartet.
  goto :fail
)

dism /Apply-Image /ImageFile:!REC_DRIVE!%IMAGE_REL% /Index:1 /ApplyDir:!WIN_DRIVE!\ /CheckIntegrity
if errorlevel 1 (
  echo FEHLER: DISM konnte das Image nicht anwenden.
  goto :fail
)

echo Wiederherstellung abgeschlossen. Kein BCDBoot wurde ausgefuehrt.
echo Installationsmedium entfernen und neu starten.
endlocal
exit /b 0

:fail
echo Vorgang beendet.
endlocal
exit /b 1

Die Kandidatensuche funktioniert nur für bereits eingebundene Volumes. Hat die versteckte RECOVERY-Partition in WinPE keinen Buchstaben, muss sie zuerst nach manueller Identifikation temporär eingebunden werden. Auch dann darf das Skript erst nach erneuter Ausgabe von list disk, list volume und dem exakten WIM-Nachweis gestartet werden.

Fazit

Die lokale Recovery-Lösung kombiniert einen kontrollierten OOBE-Zustand mit einem offline erfassten WIM und einem bewusst begrenzten Restore. Der wichtigste Sicherheitsgewinn liegt nicht im Skript, sondern in der Regel: Laufwerke nie anhand angenommener Buchstaben oder bloßer Labels auswählen, bei Mehrdeutigkeit abbrechen und ausschließlich die verifizierte Windows-Partition formatieren.